home *** CD-ROM | disk | FTP | other *** search
/ Developer CD Series 1992 June: ROMin Holiday / ADC Developer CD (1992-06) (''ROMin Holiday'')_iso / Developer Connection - 06-1992.iso / Tools & Apps / Testing & Debugging / Robix V1.0 / JG_prolog.a < prev    next >
Encoding:
Text File  |  1991-08-21  |  3.0 KB  |  92 lines  |  [TEXT/MPS ]
  1. ;
  2. ;
  3. ; Copyright © 1991, Apple Computer, Inc.
  4. ;
  5. ; by Rob Glanville
  6. ;
  7. ; 15 May 91
  8. ;
  9. ; JG_prolog.a - Startup assembly code
  10. ;
  11. ;
  12. ; Memory Map - 512kb assumed
  13. ; 00000000 - 000003FF = Interrupt Vectors
  14. ; 00000400 - 000005FF = Command buffer
  15. ; 00000600 - 00007FFF = Stack
  16. ; 00008000 - 0000FFFF = Data
  17. ; 00010000 - 00017FFF = Code
  18. ; 00018000 - 0007FFFF = Free memory
  19. ; 00080000 - 00FFFFFF = Memory mapped I/O
  20. ;
  21. ; Since this code is linked in with the application that uses it, the
  22. ; A5 data reference changes every time variables are added or subtracted.
  23. ; To pin down the data for this code, A5 is adjusted so the top of the
  24. ; data is always at 10000. It's tricky so don't fool with it!
  25. ; The main purpose of this code is to provide a stable environment for
  26. ; the C code to start with. All the real work should be done in C.
  27. ; Try not to modify this code if possible, it is just a bridge.
  28. ; 
  29. ; How this works;
  30. ; 1) The stack and data reference registers are initialized
  31. ; 2) The data segment is cleared
  32. ; 3) A key word is used to signal the Mac we're ready to go
  33. ; 4) We wait for a test command before jumping to the C code
  34.  
  35. TOS        equ    $18000        ; Top of stack
  36. TOD        equ    $fffe        ; Top of Data
  37. ClearCount    equ    $3FE        ; Clear this many 32 bit words
  38. VectorCount    equ    $fe        ; Number of vector pointers
  39. Null        equ    $00000000    ; Zero
  40. InitialSR    equ    $2700        ; Initial status register
  41. ClearStart    equ    $00000008    ; After the reset vector
  42. Pattern        equ    $00000000    ; Clear memory pattern
  43. GreenLight    equ    $00500000    ; Green light control
  44. RedLight    equ    $00400000    ; Green light control
  45. SmartMode    equ    $00600000    ; Smart mode control
  46.  
  47.     import    COMMANDLOOP
  48.  
  49. Begin    proc    export
  50.     data
  51.     import    TopOfData        ; First variable in C code
  52.     code
  53.     move.w    #InitialSR,sr        ; Clear interrupts
  54.     move.l    #TOS,sp            ; Set up the stack pointer
  55.     move.b    $CA000C,d0        ; Reset and clear
  56.     move.b    $CA0008,d0        ; Reset and clear
  57.     move.b    $C00004,d0        ; Reset and clear
  58.     move.b    $C00002,d0        ; Reset and clear
  59.     move.b    #$00,$CA000D        ; Reset and clear
  60.     move.b    #$87,$CA000F        ; Reset and clear
  61.     move.w    #$0000,$CA0008        ; Reset DMA control register
  62.     move.w    SmartMode,d0        ; Select smart mode
  63.     move.w    RedLight,d0        ; Turn on red light
  64.     move.w    d0,GreenLight        ; Turn off green light
  65.     move.l    #TOD,d0            ; Set up data pointer
  66.     move.l    #Null,a5        ; Set up data pointer
  67.     lea    TopOfData,a0        ; Get address
  68.     move.l    a0,d1            ; Copy
  69.     sub.l    d1,d0            ; Adjust
  70.     move.l    d0,a5            ; Set the data offset
  71.     move.l    #ClearCount,d0        ; Set data size
  72.     move.l    #ClearStart,a0        ; Clear pointer
  73. clear    move.l    #Pattern,(a0)+        ; Zap memory
  74.     dbra    d0,clear        ; Loop back until done
  75.     lea    UnusedInterrupt,a1    ; Get the pointer
  76.     move.l    #VectorCount,d0        ; Set vector count
  77.     move.l    #ClearStart,a0        ; Clear pointer
  78. Zap    move.l    a1,(a0)+        ; Zap memory
  79.     dbra    d0,Zap            ; Loop back until done
  80.     move.w    GreenLight,d0        ; Turn on green light
  81.     move.w    d0,RedLight        ; Turn off red light
  82.     bra.w    COMMANDLOOP        ; Enter the C code
  83.     bra.w    Begin            ; Start over if we ever return
  84.  
  85. UnusedInterrupt
  86.     move.l    #'Int0',$0        ; Set the error flag
  87.     rte                ; Interrupt return
  88.     
  89.     endp                ; End of procedure
  90.     end                ; End of source
  91.  
  92.